Créer son propre langage de programmation de A à Z
<< Évolution 2 : If/Else | Évolution 3 : Les commentaires | Évolution 4 : Les raccourcis syntaxiques >>
Commenter son code est devenu essentiel. Rappelons-nous qu'un langage de programmation n'est pas tout à fait le langage des humains. Les habitués peuvent très vite comprendre ce que fait un bout de code, mais les débutants vont mettre un peu plus de temps. Les commentaires ne sont pas qu'utiles aux autres mais aussi pour le développeur. Il peut facilement revenir sur son code si il l'a bien commenté. Parfois les commentaires ne servent pas seulement à décrire le fonctionnement mais également à marquer des choses qui seraient à revoir ou à faire. On peut aussi y mettre des renseignements utiles comme la date de création, l'auteur, la licence... Bref il est appréciable dans tout langage de programmation de pouvoir écrire du texte librement.
Évolution 3 du langage :
⚠ (:source lang=bnf linenum:)
<code > ::= <code > | <code > commentaire
(:sourcend:)
commentaire est un terminal. En fait c'est une expression régulière au même titre que variable_booleenne et variable_arithmetique. Voici la regex pour ce terminal :
⚠ (:source lang=text linenum:)
((\/\/|#).*)
(:sourcend:)
Bien donc si vous avez compris, on aura juste un lexème à rajouter dans l'analyseur lexical. Mais on voudrait aussi faire des commentaires sur plusieurs lignes. On aura un marqueur de début et un marqueur de fin. Ce sera toujours un lexème (pouvant être sur plusieurs lignes) qui devra être reconnu par l'analyseur lexical. On aura deux types de marqueurs de début et de fin donc deux lexèmes différents. Au total cela fait trois lexèmes pour un même token :
Exemples de 1er lexème :
⚠ (:source lang=text linenum:)
//blablabla
#blablabla
(:sourcend:)
Exemple de 2nd lexème (marqueurs "/*" et "*/") :
⚠ (:source lang=text linenum:)
/*
il fait chaud cet ete !!
*/
(:sourcend:)
Exemple de 3ème lexème (marqueurs " " et " ") :
⚠ (:source lang=text linenum:)
<!--
c'est pas que un commentaire en XML ou HTML, c'est aussi un commentaire en Simple !!
-->
(:sourcend:)
Pour ces trois lexèmes que l'analyseur lexical devra reconnaître, il enverra le même token à l'analyseur syntaxique. Pour ceux qui ne voyaient pas la différence entre lexème et token, ici elle est plutôt flagrante. Un token est un "code" associé à un ou plusieurs lexèmes.
⚠ (:source lang=c header="lexique_simple.lex" linenum:)
%{
<:vspace>
#include "simple.h"
unsigned int lineno=1;
bool error_lexical=false;
<:vspace>
%}
<:vspace>
%option noyywrap
<:vspace>
nombre 0|[1-9][[:digit:]]*
variable_booleenne b(_|[[:alnum:]])*
variable_arithmetique e(_|[[:alnum:]])*
<:vspace>
/* regex de commentaire d'une seule ligne */
commentaire ((\/\/|#).*)
<:vspace>
/* pour les commentaires de plusieurs lignes, on declare nos deux lexemes en tant que conditions de demarrage exclusives (%x) dans Flex */
%x commentaire_1
%x commentaire_2
<:vspace>
%%
<:vspace>
"/*" {
/* un marqueur de debut de commentaire trouve -> on lui dit que le lexeme commentaire_1 commence */
BEGIN(commentaire_1);
printf("Commentaire detecte en ligne %i\n",lineno);
}
<:vspace>
<commentaire_1>"\n" {
/* si on trouve des retours chariots et que la condition de demarrage est commentaire_1, alors on incremente la variable lineno. sans cela, on serait en decalage pour la suite de l'analyse */
lineno++;
}
<:vspace>
<commentaire_1>"*"+"/" {
/* si on au moins une fois "*" suivi de "/" et que la condition de demarrage est commentaire_1, alors on lui dit que le lexeme commentaire_1 est fini */
BEGIN(INITIAL);
printf("Fin du commentaire en ligne %i\n",lineno);
return TOK_COMMENT;
}
<:vspace>
<commentaire_1>. {/* les autres caracteres suivants la conditions de demarrage sont absorbes par l'analyse est donc ingores */}
<:vspace>
"<!--" {
BEGIN(commentaire_2);
printf("Commentaire detecte en ligne %i\n",lineno);
}
<commentaire_2>"\n" {lineno++;}
<commentaire_2>"-"+"-"+">" {
BEGIN(INITIAL);
printf("Fin du commentaire en ligne %i\n",lineno);
return TOK_COMMENT;
}
<commentaire_2>. {}
<:vspace>
{nombre} {
sscanf(yytext, "%ld", &yylval.nombre);
return TOK_NOMBRE;
}
<:vspace>
"si" {return TOK_SI;}
<:vspace>
"alors" {return TOK_ALORS;}
<:vspace>
"sinon" {return TOK_SINON;}
<:vspace>
"egal a"|"equivalent a"|"==" {return TOK_EQU;}
<:vspace>
"different de"|"!="|"<>" {return TOK_DIFF;}
<:vspace>
"superieur a"|"plus grand que"|">" {return TOK_SUP;}
<:vspace>
"inferieur a"|"plus petit que"|"<" {return TOK_INF;}
<:vspace>
"superieur ou egal a"|">=" {return TOK_SUPEQU;}
<:vspace>
"inferieur ou egal a"|"<=" {return TOK_INFEQU;}
<:vspace>
"compris dans"|"dans" {return TOK_IN;}
<:vspace>
"afficher" {return TOK_AFFICHER;}
<:vspace>
"=" {return TOK_AFFECT;}
<:vspace>
"+" {return TOK_PLUS;}
<:vspace>
"-" {return TOK_MOINS;}
<:vspace>
"*" {return TOK_MUL;}
<:vspace>
"/" {return TOK_DIV;}
<:vspace>
"(" {return TOK_PARG;}
<:vspace>
")" {return TOK_PARD;}
<:vspace>
"[" {return TOK_CROG;}
<:vspace>
"]" {return TOK_CROD;}
<:vspace>
"et" {return TOK_ET;}
<:vspace>
"ou" {return TOK_OU;}
<:vspace>
"non" {return TOK_NON;}
<:vspace>
";" {return TOK_FINSTR;}
<:vspace>
"vrai" {return TOK_VRAI;}
<:vspace>
"faux" {return TOK_FAUX;}
<:vspace>
"\n" {lineno++;}
<:vspace>
{variable_booleenne} {
yylval.texte = yytext;
return TOK_VARB;
}
<:vspace>
<:vspace>
{variable_arithmetique} {
yylval.texte = yytext;
return TOK_VARE;
}
<:vspace>
{commentaire} {
printf("Commentaire detecte en ligne %i\n",lineno);
printf("Fin du commentaire en ligne %i\n",lineno);
return TOK_COMMENT;
}
<:vspace>
" "|"\t" {}
<:vspace>
. {
fprintf(stderr,"\tERREUR : Lexeme inconnu a la ligne %d. Il s'agit de %s et comporte %d lettre(s)\n",lineno,yytext,yyleng);
error_lexical=true;
return yytext[0];
}
<:vspace>
%%
(:sourcend:)
Pour l'analyseur syntaxique, voici ce qu'on a :
⚠ (:source lang=c header="syntaxe_simple.y" linenum:)
%{
<:vspace>
#include "simple.h"
bool error_syntaxical=false;
bool error_semantical=false;
/* Notre table de hachage */
GHashTable* table_variable;
<:vspace>
/* Fonction de suppression des variables declarees a l'interieur d'un arbre syntaxique */
void supprime_variable(GNode*);
<:vspace>
/* Notre structure Variable qui a comme membre le type et un pointeur generique vers la valeur */
typedef struct Variable Variable;
<:vspace>
struct Variable{
char* type;
GNode* value;
};
<:vspace>
%}
<:vspace>
/* L'union dans Bison est utilisee pour typer nos tokens ainsi que nos non terminaux. Ici nous avons declare une union avec trois types : nombre de type int, texte de type pointeur de char (char*) et noeud d'arbre syntaxique (AST) de type (GNode*) */
<:vspace>
%union {
long nombre;
char* texte;
GNode* noeud;
}
<:vspace>
/* Nous avons ici les operateurs, ils sont definis par leur ordre de priorite. Si je definis par exemple la multiplication en premier et l'addition apres, le + l'emportera alors sur le * dans le langage. Les parenthese sont prioritaires avec %right */
<:vspace>
%left TOK_PLUS TOK_MOINS /* +- */
%left TOK_MUL TOK_DIV /* /* */
%left TOK_ET TOK_OU TOK_NON /* et ou non */
%left TOK_EQU TOK_DIFF TOK_SUP TOK_INF TOK_SUPEQU TOK_INFEQU /* comparaisons */
%right TOK_PARG TOK_PARD /* () */
<:vspace>
/* Nous avons la liste de nos expressions (les non terminaux). Nous les typons tous en noeud de l'arbre syntaxique (GNode*) */
<:vspace>
%type<noeud> code
%type<noeud> bloc_code
%type<noeud> commentaire
%type<noeud> instruction
%type<noeud> condition
%type<noeud> condition_si
%type<noeud> condition_sinon
%type<noeud> variable_arithmetique
%type<noeud> variable_booleenne
%type<noeud> affectation
%type<noeud> affichage
%type<noeud> expression_arithmetique
%type<noeud> expression_booleenne
%type<noeud> addition
%type<noeud> soustraction
%type<noeud> multiplication
%type<noeud> division
<:vspace>
/* Nous avons la liste de nos tokens (les terminaux de notre grammaire) */
<:vspace>
%token<nombre> TOK_NOMBRE
%token TOK_VRAI /* true */
%token TOK_FAUX /* false */
%token TOK_AFFECT /* = */
%token TOK_FINSTR /* ; */
%token TOK_IN /* dans */
%token TOK_CROG TOK_CROD /* [] */
%token TOK_AFFICHER /* afficher */
%token<texte> TOK_VARB /* variable booleenne */
%token<texte> TOK_VARE /* variable arithmetique */
%token TOK_SI /* si */
%token TOK_ALORS /* alors */
%token TOK_SINON /* sinon */
%token TOK_COMMENT /* commentaire */
<:vspace>
%%
<:vspace>
/* Nous definissons toutes les regles grammaticales de chaque non terminal de notre langage. Par defaut on commence a definir l'axiome, c'est a dire ici le non terminal code. Si nous le definissons pas en premier nous devons le specifier en option dans Bison avec %start */
<:vspace>
entree: code{
genere_code($1);
g_node_destroy($1);
};
<:vspace>
code: %empty{$$=g_node_new((gpointer)CODE_VIDE);}
|
code commentaire{
$$=g_node_new((gpointer)SEQUENCE);
g_node_append($$,$1);
g_node_append($$,$2);
}
|
code instruction{
printf("Resultat : C'est une instruction valide !\n\n");
$$=g_node_new((gpointer)SEQUENCE);
g_node_append($$,$1);
g_node_append($$,$2);
}
|
code error{
fprintf(stderr,"\tERREUR : Erreur de syntaxe a la ligne %d.\n",lineno);
error_syntaxical=true;
};
<:vspace>
commentaire: TOK_COMMENT{
$$=g_node_new((gpointer)CODE_VIDE);
};
bloc_code: code{
$$=g_node_new((gpointer)BLOC_CODE);
g_node_append($$,$1);
/* on efface toutes les variables declarees de la table de hachage a la sortie du bloc de code */
supprime_variable($1);
};
<:vspace>
instruction: affectation{
printf("\tInstruction type Affectation\n");
$$=$1;
}
|
affichage{
printf("\tInstruction type Affichage\n");
$$=$1;
}
|
condition{
printf("Condition si/sinon\n");
$$=$1;
};
<:vspace>
variable_arithmetique: TOK_VARE{
printf("\t\t\tVariable entiere %s\n",$1);
$$=g_node_new((gpointer)VARIABLE);
g_node_append_data($$,strdup($1));
};
<:vspace>
variable_booleenne: TOK_VARB{
printf("\t\t\tVariable booleenne %s\n",$1);
$$=g_node_new((gpointer)VARIABLE);
g_node_append_data($$,strdup($1));
};
<:vspace>
condition: condition_si TOK_FINSTR{
printf("\tCondition si\n");
$$=g_node_new((gpointer)CONDITION_SI);
g_node_append($$,$1);
}
|
condition_si condition_sinon TOK_FINSTR{
printf("\tCondition si/sinon\n");
$$=g_node_new((gpointer)CONDITION_SI_SINON);
g_node_append($$,$1);
g_node_append($$,$2);
};
<:vspace>
condition_si: TOK_SI expression_booleenne TOK_ALORS bloc_code{
$$=g_node_new((gpointer)SI);
g_node_append($$,$2);
g_node_append($$,$4);
};
<:vspace>
condition_sinon: TOK_SINON bloc_code{
$$=g_node_new((gpointer)SINON);
g_node_append($$,$2);
};
<:vspace>
affectation: variable_arithmetique TOK_AFFECT expression_arithmetique TOK_FINSTR{
/* $1 est la valeur du premier non terminal. Ici c'est la valeur du non terminal variable. $3 est la valeur du 2nd non terminal. */
printf("\t\tAffectation sur la variable\n");
Variable* var=g_hash_table_lookup(table_variable,(char*)g_node_nth_child($1,0)->data);
if(var==NULL){
/* On cree une Variable et on lui affecte le type que nous connaissons et la valeur */
var=malloc(sizeof(Variable));
if(var!=NULL){
var->type=strdup("entier");
var->value=$3;
/* On l'insere dans la table de hachage (cle: <nom_variable> / valeur: <(type,valeur)>) */
if(g_hash_table_insert(table_variable,g_node_nth_child($1,0)->data,var)){
$$=g_node_new((gpointer)AFFECTATIONE);
g_node_append($$,$1);
g_node_append($$,$3);
}else{
fprintf(stderr,"ERREUR - PROBLEME CREATION VARIABLE !\n");
exit(-1);
}
}else{
fprintf(stderr,"ERREUR - PROBLEME ALLOCATION MEMOIRE VARIABLE !\n");
exit(-1);
}
}else{
$$=g_node_new((gpointer)AFFECTATION);
g_node_append($$,$1);
g_node_append($$,$3);
}
}
|
variable_booleenne TOK_AFFECT expression_booleenne TOK_FINSTR{
/* $1 est la valeur du premier non terminal. Ici c'est la valeur du non terminal variable. $3 est la valeur du 2nd non terminal. */
printf("\t\tAffectation sur la variable\n");
Variable* var=g_hash_table_lookup(table_variable,(char*)g_node_nth_child($1,0)->data);
if(var==NULL){
/* On cree une Variable et on lui affecte le type que nous connaissons et la valeur */
var=malloc(sizeof(Variable));
if(var!=NULL){
var->type=strdup("booleen");
var->value=$3;
/* On l'insere dans la table de hachage (cle: <nom_variable> / valeur: <(type,valeur)>) */
if(g_hash_table_insert(table_variable,g_node_nth_child($1,0)->data,var)){
$$=g_node_new((gpointer)AFFECTATIONB);
g_node_append($$,$1);
g_node_append($$,$3);
}else{
fprintf(stderr,"ERREUR - PROBLEME CREATION VARIABLE !\n");
exit(-1);
}
}else{
fprintf(stderr,"ERREUR - PROBLEME ALLOCATION MEMOIRE VARIABLE !\n");
exit(-1);
}
}else{
$$=g_node_new((gpointer)AFFECTATION);
g_node_append($$,$1);
g_node_append($$,$3);
}
};
<:vspace>
affichage: TOK_AFFICHER expression_arithmetique TOK_FINSTR{
printf("\t\tAffichage de la valeur de l'expression arithmetique\n");
$$=g_node_new((gpointer)AFFICHAGEE);
g_node_append($$,$2);
}
|
TOK_AFFICHER expression_booleenne TOK_FINSTR{
printf("\t\tAffichage de la valeur de l'expression booleenne\n");
$$=g_node_new((gpointer)AFFICHAGEB);
g_node_append($$,$2);
};
<:vspace>
<:vspace>
expression_arithmetique: TOK_NOMBRE{
printf("\t\t\tNombre : %ld\n",$1);
/* Comme le token TOK_NOMBRE est de type entier et que on a type expression_arithmetique comme du texte, il nous faut convertir la valeur en texte. */
int length=snprintf(NULL,0,"%ld",$1);
char* str=malloc(length+1);
snprintf(str,length+1,"%ld",$1);
$$=g_node_new((gpointer)ENTIER);
g_node_append_data($$,strdup(str));
free(str);
}
|
variable_arithmetique{
/* On recupere un pointeur vers la structure Variable */
Variable* var=g_hash_table_lookup(table_variable,(char*)g_node_nth_child($1,0)->data);
/* Si on a trouve un pointeur valable */
if(var!=NULL){
/* On verifie que le type est bien un entier - Inutile car impose a l'analyse syntaxique */
if(strcmp(var->type,"entier")==0){
$$=$1;
}else{
fprintf(stderr,"\tERREUR : Erreur de semantique a la ligne %d. Type incompatible (entier attendu - valeur : %s) !\n",lineno,(char*)g_node_nth_child($1,0)->data);
error_semantical=true;
}
/* Sinon on conclue que la variable n'a jamais ete declaree car absente de la table */
}else{
fprintf(stderr,"\tERREUR : Erreur de semantique a la ligne %d. Variable %s jamais declaree !\n",lineno,(char*)g_node_nth_child($1,0)->data);
error_semantical=true;
}
}
|
addition{
$$=$1;
}
|
soustraction{
$$=$1;
}
|
multiplication{
$$=$1;
}
|
division{
$$=$1;
}
|
TOK_PLUS expression_arithmetique{
$$=$2;
}
|
TOK_MOINS expression_arithmetique{
printf("\t\t\tOperation unaire negation\n");
$$=g_node_new((gpointer)NEGATIF);
g_node_append($$,$2);
}
|
TOK_PARG expression_arithmetique TOK_PARD{
printf("\t\t\tC'est une expression artihmetique entre parentheses\n");
$$=g_node_new((gpointer)EXPR_PAR);
g_node_append($$,$2);
};
<:vspace>
expression_booleenne: TOK_VRAI{
printf("\t\t\tBooleen Vrai\n");
$$=g_node_new((gpointer)VRAI);
}
|
TOK_FAUX{
printf("\t\t\tBooleen Faux\n");
$$=g_node_new((gpointer)FAUX);
}
|
variable_booleenne{
/* On recupere un pointeur vers la structure Variable */
Variable* var=g_hash_table_lookup(table_variable,(char*)g_node_nth_child($1,0)->data);
/* Si on a trouve un pointeur valable */
if(var!=NULL){
/* On verifie que le type est bien un entier - Inutile car impose a l'analyse syntaxique */
if(strcmp(var->type,"booleen")==0){
$$=$1;
}else{
fprintf(stderr,"\tERREUR : Erreur de semantique a la ligne %d. Type incompatible (booleen attendu - valeur : %s) !\n",lineno,(char*)g_node_nth_child($1,0)->data);
error_semantical=true;
}
/* Sinon on conclue que la variable n'a jamais ete declaree car absente de la table */
}else{
fprintf(stderr,"\tERREUR : Erreur de semantique a la ligne %d. Variable %s jamais declaree !\n",lineno,(char*)g_node_nth_child($1,0)->data);
error_semantical=true;
}
}
|
TOK_NON expression_booleenne{
printf("\t\t\tOperation booleenne Non\n");
$$=g_node_new((gpointer)NON);
g_node_append($$,$2);
}
|
expression_booleenne TOK_ET expression_booleenne{
printf("\t\t\tOperation booleenne Et\n");
$$=g_node_new((gpointer)ET);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_booleenne TOK_OU expression_booleenne{
printf("\t\t\tOperation booleenne Ou\n");
$$=g_node_new((gpointer)OU);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
TOK_PARG expression_booleenne TOK_PARD{
printf("\t\t\tC'est une expression booleenne entre parentheses\n");
$$=g_node_new((gpointer)EXPR_PAR);
g_node_append($$,$2);
}
|
expression_booleenne TOK_EQU expression_booleenne{
printf("\t\t\tOperateur d'egalite ==\n");
$$=g_node_new((gpointer)EGALITE);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_booleenne TOK_DIFF expression_booleenne{
printf("\t\t\tOperateur d'inegalite !=\n");
$$=g_node_new((gpointer)DIFFERENT);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_EQU expression_arithmetique{
printf("\t\t\tOperateur d'egalite ==\n");
$$=g_node_new((gpointer)EGALITE);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_DIFF expression_arithmetique{
printf("\t\t\tOperateur d'inegalite !=\n");
$$=g_node_new((gpointer)DIFFERENT);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_SUP expression_arithmetique{
printf("\t\t\tOperateur de superiorite >\n");
$$=g_node_new((gpointer)SUPERIEUR);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_INF expression_arithmetique{
printf("\t\t\tOperateur d'inferiorite <\n");
$$=g_node_new((gpointer)INFERIEUR);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_SUPEQU expression_arithmetique{
printf("\t\t\tOperateur >=\n");
$$=g_node_new((gpointer)SUPEGAL);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_INFEQU expression_arithmetique{
printf("\t\t\tOperateur <=\n");
$$=g_node_new((gpointer)INFEGAL);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_IN TOK_CROG expression_arithmetique TOK_FINSTR expression_arithmetique TOK_CROD{
printf("\t\t\tOperateur dans\n");
$$=g_node_new((gpointer)DANSII);
g_node_append($$,$1);
g_node_append($$,$4);
g_node_append($$,$6);
}
|
expression_arithmetique TOK_IN TOK_CROD expression_arithmetique TOK_FINSTR expression_arithmetique TOK_CROD{
printf("\t\t\tOperateur dans\n");
$$=g_node_new((gpointer)DANSEI);
g_node_append($$,$1);
g_node_append($$,$4);
g_node_append($$,$6);
}
|
expression_arithmetique TOK_IN TOK_CROG expression_arithmetique TOK_FINSTR expression_arithmetique TOK_CROG{
printf("\t\t\tOperateur dans\n");
$$=g_node_new((gpointer)DANSIE);
g_node_append($$,$1);
g_node_append($$,$4);
g_node_append($$,$6);
}
|
expression_arithmetique TOK_IN TOK_CROD expression_arithmetique TOK_FINSTR expression_arithmetique TOK_CROG{
printf("\t\t\tOperateur dans\n");
$$=g_node_new((gpointer)DANSEE);
g_node_append($$,$1);
g_node_append($$,$4);
g_node_append($$,$6);
};
<:vspace>
addition: expression_arithmetique TOK_PLUS expression_arithmetique{
printf("\t\t\tAddition\n");
$$=g_node_new((gpointer)ADDITION);
g_node_append($$,$1);
g_node_append($$,$3);
};
<:vspace>
soustraction: expression_arithmetique TOK_MOINS expression_arithmetique{
printf("\t\t\tSoustraction\n");
$$=g_node_new((gpointer)SOUSTRACTION);
g_node_append($$,$1);
g_node_append($$,$3);
};
<:vspace>
multiplication: expression_arithmetique TOK_MUL expression_arithmetique{
printf("\t\t\tMultiplication\n");
$$=g_node_new((gpointer)MULTIPLICATION);
g_node_append($$,$1);
g_node_append($$,$3);
};
<:vspace>
division: expression_arithmetique TOK_DIV expression_arithmetique{
printf("\t\t\tDivision\n");
$$=g_node_new((gpointer)DIVISION);
g_node_append($$,$1);
g_node_append($$,$3);
};
<:vspace>
%%
<:vspace>
/* Dans la fonction main on appelle bien la routine yyparse() qui sera genere par Bison. Cette routine appellera yylex() de notre analyseur lexical. */
<:vspace>
int main(int argc, char** argv){
/* recuperation du nom de fichier d'entree (langage Simple) donne en parametre */
char* fichier_entree=strdup(argv[1]);
/* ouverture du fichier en lecture dans le flux d'entree stdin */
stdin=fopen(fichier_entree,"r");
/* creation fichier de sortie (langage C) */
char* fichier_sortie=strdup(argv[1]);
/* remplace l'extension par .c */
strcpy(rindex(fichier_sortie, '.'), ".c");
/* ouvre le fichier cree en ecriture */
fichier=fopen(fichier_sortie, "w");
/* Creation de la table de hachage */
table_variable=g_hash_table_new_full(g_str_hash,g_str_equal,free,free);
printf("Debut de l'analyse syntaxique :\n");
debut_code();
yyparse();
fin_code();
printf("Fin de l'analyse !\n");
printf("Resultat :\n");
if(error_lexical){
printf("\t-- Echec : Certains lexemes ne font pas partie du lexique du langage ! --\n");
printf("\t-- Echec a l'analyse lexicale --\n");
}
else{
printf("\t-- Succes a l'analyse lexicale ! --\n");
}
if(error_syntaxical){
printf("\t-- Echec : Certaines phrases sont syntaxiquement incorrectes ! --\n");
printf("\t-- Echec a l'analyse syntaxique --\n");
}
else{
printf("\t-- Succes a l'analyse syntaxique ! --\n");
if(error_semantical){
printf("\t-- Echec : Certaines phrases sont semantiquement incorrectes ! --\n");
printf("\t-- Echec a l'analyse semantique --\n");
}
else{
printf("\t-- Succes a l'analyse semantique ! --\n");
}
}
/* Suppression du fichier genere si erreurs analyse */
if(error_lexical||error_syntaxical||error_semantical){
remove(fichier_sortie);
printf("ECHEC GENERATION CODE !\n");
}
else{
printf("Le fichier \"%s\" a ete genere !\n",fichier_sortie);
}
/* Fermeture des flux */
fclose(fichier);
fclose(stdin);
/* Liberation memoire */
free(fichier_entree);
free(fichier_sortie);
g_hash_table_destroy(table_variable);
return EXIT_SUCCESS;
}
<:vspace>
void yyerror(char *s) {
fprintf(stderr, "Erreur de syntaxe a la ligne %d: %s\n", lineno, s);
}
<:vspace>
/* Cette fonction supprime dans la table de hachage toutes les variables declarees pour la premiere fois dans l'arbre syntaxique donne en parametre */
<:vspace>
void supprime_variable(GNode* ast){
/* si l'element est n'est pas NULL et que ce n'est pas une feuille et que ce n'est pas un noeud d'arbre type bloc_code (pour eviter de supprimer des variables deja supprimees dans le cas ou on aurait des blocs de code dans des blocs de code */*/
if(ast&&!G_NODE_IS_LEAF(ast)&&(long)ast->data!=BLOC_CODE){
/* si le noeud est de type declaration */
if((long)ast->data==AFFECTATIONB||(long)ast->data==AFFECTATIONE){
/* suppression de la variable dans la table de hachage */
if(g_hash_table_remove(table_variable,(char*)g_node_nth_child(g_node_nth_child(ast,0),0)->data)){
printf("Variable supprimee !\n");
}else{
fprintf(stderr,"ERREUR - PROBLEME DE SUPPRESSION VARIABLE !\n");
exit(-1);
}
/* sinon on continue de parcourir l'arbre */
}else{
int nb_enfant;
for(nb_enfant=0;nb_enfant<=g_node_n_children(ast);nb_enfant++){
supprime_variable(g_node_nth_child(ast,nb_enfant));
}
}
}
}
(:sourcend:)
Et... c'est tout ! Si vous êtes des chefs, vous savez qu'on n'a besoin de toucher au générateur de code ni au fichier d'entête. On compile et on teste avec un programme contenant des commentaires :
⚠ (:source lang=text header="programme.simple" linenum:)
/*
<:vspace>
Les commentaires peuvent etre sur une ou plusieurs lignes entre "%comment% " et " %%"
<:vspace>
*/
<:vspace>
<!------------------------------------<
<:vspace>
Fichier : programme.simple
Date : 19 juillet 2016
<:vspace>
Auteur : Thomas Tributsch (totodunet)
<:vspace>
Lieu : Business & Decision - Niort
<:vspace>
>!------------------------------------>
<:vspace>
# DECLARATION DES VARIABLES #
entier = 10;
booleen = vrai ou faux;
<:vspace>
// CONDIION //
<:vspace>
#si booleen est faux, on affiche la variable entier
si non booleen alors
afficher entier;
//sinon on affiche la valeur + 1 de la variable entier
sinon
afficher entier+1;
;
<:vspace>
<!--
<:vspace>
Les commentaires peuvent etre sur une ou plusieurs lignes entre "/*" et "*/"
<:vspace>
-->
(:sourcend:)
La sortie du compilateur affiche :
⚠ (:source lang=text:)
Debut de l'analyse syntaxique :
Commentaire detecte en ligne 1
Fin du commentaire en ligne 5
Commentaire detecte en ligne 7
Fin du commentaire en ligne 16
Commentaire detecte en ligne 18
Fin du commentaire en ligne 18
Variable entiere entier
Nombre : 10
Affectation sur la variable
Instruction type Affectation
Resultat : C'est une instruction valide !
<:vspace>
Variable booleenne booleen
Booleen Vrai
Booleen Faux
Operation booleenne Ou
Affectation sur la variable
Instruction type Affectation
Resultat : C'est une instruction valide !
<:vspace>
Commentaire detecte en ligne 22
Fin du commentaire en ligne 22
Commentaire detecte en ligne 24
Fin du commentaire en ligne 24
Variable booleenne booleen
Operation booleenne Non
Variable entiere entier
Affichage de la valeur de l'expression arithmetique
Instruction type Affichage
Resultat : C'est une instruction valide !
<:vspace>
Commentaire detecte en ligne 27
Fin du commentaire en ligne 27
Variable entiere entier
Nombre : 1
Addition
Affichage de la valeur de l'expression arithmetique
Instruction type Affichage
Resultat : C'est une instruction valide !
<:vspace>
Condition si/sinon
Condition si/sinon
Resultat : C'est une instruction valide !
<:vspace>
Commentaire detecte en ligne 32
Fin du commentaire en ligne 36
Fin de l'analyse !
Resultat :
-- Succes a l'analyse lexicale ! --
-- Succes a l'analyse syntaxique ! --
-- Succes a l'analyse semantique ! --
Le fichier "programme.c" a ete genere !
(:sourcend:)
On peut compiler le programme C généré et l'exécuter :
⚠ (:source lang=text:)
11
(:sourcend:)
Bon je vous dis à la prochaine évolution !! Ce sera une petite évolution. On implémentera quelques syntaxes utiles à savoir les affectations rapides sur une variable entière et booléeenne : ("++","+=","--","-=","/=,"*=","|=","&=") et l'opérateur arithmétique modulo. Je profiterai pour rajouter le lexème "!" pour le token TOK_NON utilisé dans la syntaxe de l'opération booléenne unaire non.
<< Évolution 2 : If/Else | Évolution 3 : Les commentaires | Évolution 4 : Les raccourcis syntaxiques >>
Thomas - (CC BY-NC-SA 3.0 FR)
