Créer son propre langage de programmation de A à Z
<< Arbre syntaxique abstrait et Génération de code | Évolution 1 : Opérateurs de comparaison | Évolution 2 : If/Else >>
L'évolution 1 consiste à implémenter les opérateurs de comparaison. On va agrandir le nombre de règles syntaxiques pour le non terminal représentant les expressions booléennes.
Évolution 1 du langage :
⚠ (:source lang=bnf linenum:)
<expression_booleenne> ::= variable | "vrai" | "faux" | <et> | <ou> | <non> | "(" <expression_booleenne> ")" | <egal> | <inferieur> | <superieur> | <different> | <inclus> | <inferieur_egal> | <superieur_egal>
<:vspace>
<egal> ::= <expression_booleenne> "==" <expression_booleenne> | <expression_arithmetique> "==" <expression_arithmetique> | <expression_booleenne> "egal a" <expression_booleenne> | <expression_arithmetique> "egal a" <expression_arithmetique>
<:vspace>
<inferieur> ::= <expression_arithmetique> "<" <expression_arithmetique> | <expression_arithmetique> "inferieur a" <expression_arithmetique>
<:vspace>
<superieur> ::= <expression_arithmetique> ">" <expression_arithmetique> | <expression_arithmetique> "superieur a" <expression_arithmetique>
<:vspace>
<different> ::= <expression_booleenne> "!=" <expression_booleenne> | <expression_arithmetique> "!=" <expression_arithmetique> | <expression_booleenne> "<>" <expression_booleenne> | <expression_arithmetique> "<>" <expression_arithmetique> | <expression_booleenne> "different de" <expression_booleenne> | <expression_arithmetique> "different de" <expression_arithmetique>
<:vspace>
<inferieur_egal> ::= <expression_arithmetique> "<=" <expression_arithmetique> | <expression_arithmetique> "inferieur ou egal a" <expression_arithmetique>
<:vspace>
<superieur_egal> ::= <expression_arithmetique> ">=" <expression_arithmetique> | <expression_arithmetique> "superieur ou egal a" <expression_arithmetique>
<:vspace>
<inclus> ::= <expression_arithmetique> "dans" <crochet> <expression_arithmetique> ";" <expression_arithmetique> <crochet> | <expression_arithmetique> "compris dans" <crochet> <expression_arithmetique> ";" <expression_arithmetique> <crochet>
<:vspace>
<crochet> ::= "[" | "]"
(:sourcend:)
On donne à l'analyseur lexical connaissance des nouveaux lexèmes :
⚠ (:source lang=c header="lexique_simple.lex" linenum:)
%{
<:vspace>
#include "simple.h"
unsigned int lineno=1;
bool error_lexical=false;
<:vspace>
%}
<:vspace>
%option noyywrap
<:vspace>
nombre 0|[1-9][[:digit:]]*
variable_booleenne b(_|[[:alnum:]])*
variable_arithmetique e(_|[[:alnum:]])*
<:vspace>
%%
<:vspace>
{nombre} {
sscanf(yytext, "%ld", &yylval.nombre);
return TOK_NOMBRE;
}
<:vspace>
"egal a"|"equivalent a"|"==" {return TOK_EQU;}
<:vspace>
"different de"|"!="|"<>" {return TOK_DIFF;}
<:vspace>
"superieur a"|"plus grand que"|">" {return TOK_SUP;}
<:vspace>
"inferieur a"|"plus petit que"|"<" {return TOK_INF;}
<:vspace>
"superieur ou egal a"|">=" {return TOK_SUPEQU;}
<:vspace>
"inferieur ou egal a"|"<=" {return TOK_INFEQU;}
<:vspace>
"compris dans"|"dans" {return TOK_IN;}
<:vspace>
"afficher" {return TOK_AFFICHER;}
<:vspace>
"=" {return TOK_AFFECT;}
<:vspace>
"+" {return TOK_PLUS;}
<:vspace>
"-" {return TOK_MOINS;}
<:vspace>
"*" {return TOK_MUL;}
<:vspace>
"/" {return TOK_DIV;}
<:vspace>
"(" {return TOK_PARG;}
<:vspace>
")" {return TOK_PARD;}
<:vspace>
"[" {return TOK_CROG;}
<:vspace>
"]" {return TOK_CROD;}
<:vspace>
"et" {return TOK_ET;}
<:vspace>
"ou" {return TOK_OU;}
<:vspace>
"non" {return TOK_NON;}
<:vspace>
";" {return TOK_FINSTR;}
<:vspace>
"vrai" {return TOK_VRAI;}
<:vspace>
"faux" {return TOK_FAUX;}
<:vspace>
"\n" {lineno++;}
<:vspace>
{variable_booleenne} {
yylval.texte = yytext;
return TOK_VARB;
}
<:vspace>
<:vspace>
{variable_arithmetique} {
yylval.texte = yytext;
return TOK_VARE;
}
<:vspace>
" "|"\t" {}
<:vspace>
. {
fprintf(stderr,"\tERREUR : Lexeme inconnu a la ligne %d. Il s'agit de %s et comporte %d lettre(s)\n",lineno,yytext,yyleng);
error_lexical=true;
return yytext[0];
}
<:vspace>
%%
(:sourcend:)
On ajoute ces nouvelles déclarations à la fin du fichier d'entête :
⚠ (:source lang=c header="simple.h" linestart=40 linenum:)
#define EGALITE 19
#define DIFFERENT 20
#define SUPERIEUR 21
#define INFERIEUR 22
#define SUPEGAL 23
#define INFEGAL 24
#define DANSII 25 /* inclus-inclus */
#define DANSEI 26 /* exclus-inclus */
#define DANSIE 27 /* inclus-exclus */
#define DANSEE 28 /* exclus-exclus */
(:sourcend:)
On met à jour l'analyseur syntaxique Bison :
⚠ (:source lang=c header="syntaxe_simple.y" linenum:)
%{
<:vspace>
#include "simple.h"
bool error_syntaxical=false;
bool error_semantical=false;
/* Notre table de hachage */
GHashTable* table_variable;
<:vspace>
/* Notre structure Variable qui a comme membre le type et un pointeur generique vers la valeur */
typedef struct Variable Variable;
<:vspace>
struct Variable{
char* type;
GNode* value;
};
<:vspace>
%}
<:vspace>
/* L'union dans Bison est utilisee pour typer nos tokens ainsi que nos non terminaux. Ici nous avons declare une union avec trois types : nombre de type int, texte de type pointeur de char (char*) et noeud d'arbre syntaxique (AST) de type (GNode*) */
<:vspace>
%union {
long nombre;
char* texte;
GNode* noeud;
}
<:vspace>
/* Nous avons ici les operateurs, ils sont definis par leur ordre de priorite. Si je definis par exemple la multiplication en premier et l'addition apres, le + l'emportera alors sur le * dans le langage. Les parenthese sont prioritaires avec %right */
<:vspace>
%left TOK_PLUS TOK_MOINS /* +- */
%left TOK_MUL TOK_DIV /* /* */
%left TOK_ET TOK_OU TOK_NON /* et ou non */
%left TOK_EQU TOK_DIFF TOK_SUP TOK_INF TOK_SUPEQU TOK_INFEQU /* comparaisons */
%right TOK_PARG TOK_PARD /* () */
<:vspace>
/* Nous avons la liste de nos expressions (les non terminaux). Nous les typons tous en noeud de l'arbre syntaxique (GNode*) */
<:vspace>
%type<noeud> code
%type<noeud> instruction
%type<noeud> variable_arithmetique
%type<noeud> variable_booleenne
%type<noeud> affectation
%type<noeud> affichage
%type<noeud> expression_arithmetique
%type<noeud> expression_booleenne
%type<noeud> addition
%type<noeud> soustraction
%type<noeud> multiplication
%type<noeud> division
<:vspace>
/* Nous avons la liste de nos tokens (les terminaux de notre grammaire) */
<:vspace>
%token<nombre> TOK_NOMBRE
%token TOK_VRAI /* true */
%token TOK_FAUX /* false */
%token TOK_AFFECT /* = */
%token TOK_FINSTR /* ; */
%token TOK_IN /* dans */
%token TOK_CROG TOK_CROD /* [] */
%token TOK_AFFICHER /* afficher */
%token<texte> TOK_VARB /* variable booleenne */
%token<texte> TOK_VARE /* variable arithmetique */
<:vspace>
%%
<:vspace>
/* Nous definissons toutes les regles grammaticales de chaque non terminal de notre langage. Par defaut on commence a definir l'axiome, c'est a dire ici le non terminal code. Si nous le definissons pas en premier nous devons le specifier en option dans Bison avec %start */
<:vspace>
entree: code{
genere_code($1);
g_node_destroy($1);
};
<:vspace>
code: %empty{$$=g_node_new((gpointer)CODE_VIDE);}
|
code instruction{
printf("Resultat : C'est une instruction valide !\n\n");
$$=g_node_new((gpointer)SEQUENCE);
g_node_append($$,$1);
g_node_append($$,$2);
}
|
code error{
fprintf(stderr,"\tERREUR : Erreur de syntaxe a la ligne %d.\n",lineno);
error_syntaxical=true;
};
<:vspace>
instruction: affectation{
printf("\tInstruction type Affectation\n");
$$=$1;
}
|
affichage{
printf("\tInstruction type Affichage\n");
$$=$1;
};
<:vspace>
variable_arithmetique: TOK_VARE{
printf("\t\t\tVariable entiere %s\n",$1);
$$=g_node_new((gpointer)VARIABLE);
g_node_append_data($$,strdup($1));
};
<:vspace>
variable_booleenne: TOK_VARB{
printf("\t\t\tVariable booleenne %s\n",$1);
$$=g_node_new((gpointer)VARIABLE);
g_node_append_data($$,strdup($1));
};
<:vspace>
affectation: variable_arithmetique TOK_AFFECT expression_arithmetique TOK_FINSTR{
/* $1 est la valeur du premier non terminal. Ici c'est la valeur du non terminal variable. $3 est la valeur du 2nd non terminal. */
printf("\t\tAffectation sur la variable\n");
Variable* var=g_hash_table_lookup(table_variable,(char*)g_node_nth_child($1,0)->data);
if(var==NULL){
/* On cree une Variable et on lui affecte le type que nous connaissons et la valeur */
var=malloc(sizeof(Variable));
if(var!=NULL){
var->type=strdup("entier");
var->value=$3;
/* On l'insere dans la table de hachage (cle: <nom_variable> / valeur: <(type,valeur)>) */
if(g_hash_table_insert(table_variable,g_node_nth_child($1,0)->data,var)){
$$=g_node_new((gpointer)AFFECTATIONE);
g_node_append($$,$1);
g_node_append($$,$3);
}else{
fprintf(stderr,"ERREUR - PROBLEME CREATION VARIABLE !\n");
exit(-1);
}
}else{
fprintf(stderr,"ERREUR - PROBLEME ALLOCATION MEMOIRE VARIABLE !\n");
exit(-1);
}
}else{
$$=g_node_new((gpointer)AFFECTATION);
g_node_append_data($$,$1);
g_node_append($$,$3);
}
}
|
variable_booleenne TOK_AFFECT expression_booleenne TOK_FINSTR{
/* $1 est la valeur du premier non terminal. Ici c'est la valeur du non terminal variable. $3 est la valeur du 2nd non terminal. */
printf("\t\tAffectation sur la variable\n");
Variable* var=g_hash_table_lookup(table_variable,(char*)g_node_nth_child($1,0)->data);
if(var==NULL){
/* On cree une Variable et on lui affecte le type que nous connaissons et la valeur */
var=malloc(sizeof(Variable));
if(var!=NULL){
var->type=strdup("booleen");
var->value=$3;
/* On l'insere dans la table de hachage (cle: <nom_variable> / valeur: <(type,valeur)>) */
if(g_hash_table_insert(table_variable,g_node_nth_child($1,0)->data,var)){
$$=g_node_new((gpointer)AFFECTATIONE);
g_node_append($$,$1);
g_node_append($$,$3);
}else{
fprintf(stderr,"ERREUR - PROBLEME CREATION VARIABLE !\n");
exit(-1);
}
}else{
fprintf(stderr,"ERREUR - PROBLEME ALLOCATION MEMOIRE VARIABLE !\n");
exit(-1);
}
}else{
$$=g_node_new((gpointer)AFFECTATION);
g_node_append($$,$1);
g_node_append($$,$3);
}
};
<:vspace>
affichage: TOK_AFFICHER expression_arithmetique TOK_FINSTR{
printf("\t\tAffichage de la valeur de l'expression arithmetique\n");
$$=g_node_new((gpointer)AFFICHAGEE);
g_node_append($$,$2);
}
|
TOK_AFFICHER expression_booleenne TOK_FINSTR{
printf("\t\tAffichage de la valeur de l'expression booleenne\n");
$$=g_node_new((gpointer)AFFICHAGEB);
g_node_append($$,$2);
};
<:vspace>
<:vspace>
expression_arithmetique: TOK_NOMBRE{
printf("\t\t\tNombre : %ld\n",$1);
/* Comme le token TOK_NOMBRE est de type entier et que on a type expression_arithmetique comme du texte, il nous faut convertir la valeur en texte. */
int length=snprintf(NULL,0,"%ld",$1);
char* str=malloc(length+1);
snprintf(str,length+1,"%ld",$1);
$$=g_node_new((gpointer)ENTIER);
g_node_append_data($$,strdup(str));
free(str);
}
|
variable_arithmetique{
/* On recupere un pointeur vers la structure Variable */
Variable* var=g_hash_table_lookup(table_variable,(char*)g_node_nth_child($1,0)->data);
/* Si on a trouve un pointeur valable */
if(var!=NULL){
/* On verifie que le type est bien un entier - Inutile car impose a l'analyse syntaxique */
if(strcmp(var->type,"entier")==0){
$$=$1;
}else{
fprintf(stderr,"\tERREUR : Erreur de semantique a la ligne %d. Type incompatible (entier attendu - valeur : %s) !\n",lineno,(char*)g_node_nth_child($1,0)->data);
error_semantical=true;
}
/* Sinon on conclue que la variable n'a jamais ete declaree car absente de la table */
}else{
fprintf(stderr,"\tERREUR : Erreur de semantique a la ligne %d. Variable %s jamais declaree !\n",lineno,(char*)g_node_nth_child($1,0)->data);
error_semantical=true;
}
}
|
addition{
$$=$1;
}
|
soustraction{
$$=$1;
}
|
multiplication{
$$=$1;
}
|
division{
$$=$1;
}
|
TOK_PARG expression_arithmetique TOK_PARD{
printf("\t\t\tC'est une expression artihmetique entre parentheses\n");
$$=g_node_new((gpointer)EXPR_PAR);
g_node_append($$,$2);
};
<:vspace>
expression_booleenne: TOK_VRAI{
printf("\t\t\tBooleen Vrai\n");
$$=g_node_new((gpointer)VRAI);
}
|
TOK_FAUX{
printf("\t\t\tBooleen Faux\n");
$$=g_node_new((gpointer)FAUX);
}
|
variable_booleenne{
/* On recupere un pointeur vers la structure Variable */
Variable* var=g_hash_table_lookup(table_variable,(char*)g_node_nth_child($1,0)->data);
/* Si on a trouve un pointeur valable */
if(var!=NULL){
/* On verifie que le type est bien un entier - Inutile car impose a l'analyse syntaxique */
if(strcmp(var->type,"booleen")==0){
$$=$1;
}else{
fprintf(stderr,"\tERREUR : Erreur de semantique a la ligne %d. Type incompatible (booleen attendu - valeur : %s) !\n",lineno,(char*)g_node_nth_child($1,0)->data);
error_semantical=true;
}
/* Sinon on conclue que la variable n'a jamais ete declaree car absente de la table */
}else{
fprintf(stderr,"\tERREUR : Erreur de semantique a la ligne %d. Variable %s jamais declaree !\n",lineno,(char*)g_node_nth_child($1,0)->data);
error_semantical=true;
}
}
|
TOK_NON expression_booleenne{
printf("\t\t\tOperation booleenne Non\n");
$$=g_node_new((gpointer)NON);
g_node_append($$,$2);
}
|
expression_booleenne TOK_ET expression_booleenne{
printf("\t\t\tOperation booleenne Et\n");
$$=g_node_new((gpointer)ET);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_booleenne TOK_OU expression_booleenne{
printf("\t\t\tOperation booleenne Ou\n");
$$=g_node_new((gpointer)OU);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
TOK_PARG expression_booleenne TOK_PARD{
printf("\t\t\tC'est une expression booleenne entre parentheses\n");
$$=g_node_new((gpointer)EXPR_PAR);
g_node_append($$,$2);
}
|
expression_booleenne TOK_EQU expression_booleenne{
printf("\t\t\tOperateur d'egalite ==\n");
$$=g_node_new((gpointer)EGALITE);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_booleenne TOK_DIFF expression_booleenne{
printf("\t\t\tOperateur d'inegalite !=\n");
$$=g_node_new((gpointer)DIFFERENT);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_EQU expression_arithmetique{
printf("\t\t\tOperateur d'egalite ==\n");
$$=g_node_new((gpointer)EGALITE);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_DIFF expression_arithmetique{
printf("\t\t\tOperateur d'inegalite !=\n");
$$=g_node_new((gpointer)DIFFERENT);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_SUP expression_arithmetique{
printf("\t\t\tOperateur de superiorite >\n");
$$=g_node_new((gpointer)SUPERIEUR);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_INF expression_arithmetique{
printf("\t\t\tOperateur d'inferiorite <\n");
$$=g_node_new((gpointer)INFERIEUR);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_SUPEQU expression_arithmetique{
printf("\t\t\tOperateur >=\n");
$$=g_node_new((gpointer)SUPEGAL);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_INFEQU expression_arithmetique{
printf("\t\t\tOperateur <=\n");
$$=g_node_new((gpointer)INFEGAL);
g_node_append($$,$1);
g_node_append($$,$3);
}
|
expression_arithmetique TOK_IN TOK_CROG expression_arithmetique TOK_FINSTR expression_arithmetique TOK_CROD{
printf("\t\t\tOperateur dans\n");
$$=g_node_new((gpointer)DANSII);
g_node_append($$,$1);
g_node_append($$,$4);
g_node_append($$,$6);
}
|
expression_arithmetique TOK_IN TOK_CROD expression_arithmetique TOK_FINSTR expression_arithmetique TOK_CROD{
printf("\t\t\tOperateur dans\n");
$$=g_node_new((gpointer)DANSEI);
g_node_append($$,$1);
g_node_append($$,$4);
g_node_append($$,$6);
}
|
expression_arithmetique TOK_IN TOK_CROG expression_arithmetique TOK_FINSTR expression_arithmetique TOK_CROG{
printf("\t\t\tOperateur dans\n");
$$=g_node_new((gpointer)DANSIE);
g_node_append($$,$1);
g_node_append($$,$4);
g_node_append($$,$6);
}
|
expression_arithmetique TOK_IN TOK_CROD expression_arithmetique TOK_FINSTR expression_arithmetique TOK_CROG{
printf("\t\t\tOperateur dans\n");
$$=g_node_new((gpointer)DANSEE);
g_node_append($$,$1);
g_node_append($$,$4);
g_node_append($$,$6);
};
<:vspace>
addition: expression_arithmetique TOK_PLUS expression_arithmetique{
printf("\t\t\tAddition\n");
$$=g_node_new((gpointer)ADDITION);
g_node_append($$,$1);
g_node_append($$,$3);
};
<:vspace>
soustraction: expression_arithmetique TOK_MOINS expression_arithmetique{
printf("\t\t\tSoustraction\n");
$$=g_node_new((gpointer)SOUSTRACTION);
g_node_append($$,$1);
g_node_append($$,$3);
};
<:vspace>
multiplication: expression_arithmetique TOK_MUL expression_arithmetique{
printf("\t\t\tMultiplication\n");
$$=g_node_new((gpointer)MULTIPLICATION);
g_node_append($$,$1);
g_node_append($$,$3);
};
<:vspace>
division: expression_arithmetique TOK_DIV expression_arithmetique{
printf("\t\t\tDivision\n");
$$=g_node_new((gpointer)DIVISION);
g_node_append($$,$1);
g_node_append($$,$3);
};
<:vspace>
%%
<:vspace>
/* Dans la fonction main on appelle bien la routine yyparse() qui sera genere par Bison. Cette routine appellera yylex() de notre analyseur lexical. */
<:vspace>
int main(int argc, char** argv){
/* recuperation du nom de fichier d'entree (langage Simple) donne en parametre */
char* fichier_entree=strdup(argv[1]);
/* ouverture du fichier en lecture dans le flux d'entree stdin */
stdin=fopen(fichier_entree,"r");
/* creation fichier de sortie (langage C) */
char* fichier_sortie=strdup(argv[1]);
/* remplace l'extension par .c */
strcpy(rindex(fichier_sortie, '.'), ".c");
/* ouvre le fichier cree en ecriture */
fichier=fopen(fichier_sortie, "w");
/* Creation de la table de hachage */
table_variable=g_hash_table_new_full(g_str_hash,g_str_equal,free,free);
printf("Debut de l'analyse syntaxique :\n");
debut_code();
yyparse();
fin_code();
printf("Fin de l'analyse !\n");
printf("Resultat :\n");
if(error_lexical){
printf("\t-- Echec : Certains lexemes ne font pas partie du lexique du langage ! --\n");
printf("\t-- Echec a l'analyse lexicale --\n");
}
else{
printf("\t-- Succes a l'analyse lexicale ! --\n");
}
if(error_syntaxical){
printf("\t-- Echec : Certaines phrases sont syntaxiquement incorrectes ! --\n");
printf("\t-- Echec a l'analyse syntaxique --\n");
}
else{
printf("\t-- Succes a l'analyse syntaxique ! --\n");
if(error_semantical){
printf("\t-- Echec : Certaines phrases sont semantiquement incorrectes ! --\n");
printf("\t-- Echec a l'analyse semantique --\n");
}
else{
printf("\t-- Succes a l'analyse semantique ! --\n");
}
}
/* Suppression du fichier genere si erreurs analyse */
if(error_lexical||error_syntaxical||error_semantical){
remove(fichier_sortie);
printf("ECHEC GENERATION CODE !\n");
}
else{
printf("Le fichier \"%s\" a ete genere !\n",fichier_sortie);
}
/* Fermeture des flux */
fclose(fichier);
fclose(stdin);
/* Liberation memoire */
free(fichier_entree);
free(fichier_sortie);
g_hash_table_destroy(table_variable);
return EXIT_SUCCESS;
}
<:vspace>
void yyerror(char *s) {
fprintf(stderr, "Erreur de syntaxe a la ligne %d: %s\n", lineno, s);
}
(:sourcend:)
Et on doit mettre à jour aussi le générateur de code C. A rajouter dans le switch de la fonction genere_code() :
⚠ (:source lang=c header="generation_code.c" linestart=103 linenum:)
case EGALITE:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,"==");
genere_code(g_node_nth_child(ast,1));
break;
case DIFFERENT:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,"!=");
genere_code(g_node_nth_child(ast,1));
break;
case INFERIEUR:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,"<");
genere_code(g_node_nth_child(ast,1));
break;
case SUPERIEUR:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,">");
genere_code(g_node_nth_child(ast,1));
break;
case INFEGAL:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,"<=");
genere_code(g_node_nth_child(ast,1));
break;
case SUPEGAL:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,">=");
genere_code(g_node_nth_child(ast,1));
break;
case DANSII:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,">=");
genere_code(g_node_nth_child(ast,1));
fprintf(fichier,"&&");
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,"<=");
genere_code(g_node_nth_child(ast,2));
break;
case DANSEI:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,">");
genere_code(g_node_nth_child(ast,1));
fprintf(fichier,"&&");
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,"<=");
genere_code(g_node_nth_child(ast,2));
break;
case DANSIE:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,">=");
genere_code(g_node_nth_child(ast,1));
fprintf(fichier,"&&");
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,"<");
genere_code(g_node_nth_child(ast,2));
break;
case DANSEE:
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,">");
genere_code(g_node_nth_child(ast,1));
fprintf(fichier,"&&");
genere_code(g_node_nth_child(ast,0));
fprintf(fichier,"<");
genere_code(g_node_nth_child(ast,2));
break;
(:sourcend:)
Voilà ! On n'oublie pas de tout compiler :
⚠ (:source lang=bash:)
flex -o lexique_simple.c lexique_simple.lex
bison -d syntaxe_simple.y
gcc lexique_simple.c syntaxe_simple.tab.c generation_code.c `pkg-config --cflags --libs glib-2.0` -o simple
(:sourcend:)
Maintenant passons lui un fichier test :
⚠ (:source lang=text header="programme.simple" linenum:)
entier = 6;
epentier = 30;
booleen = vrai;
bnbool = faux;
<:vspace>
afficher booleen == bnbool;
afficher booleen egal a bnbool;
<:vspace>
afficher booleen == booleen;
afficher bnbool egal a bnbool;
<:vspace>
<:vspace>
afficher booleen != booleen;
afficher bnbool different de bnbool;
afficher bnbool <> bnbool;
<:vspace>
afficher booleen != bnbool;
afficher booleen different de bnbool;
afficher booleen <> bnbool;
<:vspace>
<:vspace>
afficher entier == epentier;
afficher entier egal a epentier;
<:vspace>
afficher entier == entier;
afficher epentier egal a epentier;
<:vspace>
<:vspace>
afficher entier != entier;
afficher epentier different de epentier;
afficher epentier <> epentier;
<:vspace>
afficher entier != epentier;
afficher entier different de epentier;
afficher entier <> epentier;
<:vspace>
<:vspace>
afficher entier > epentier;
afficher entier superieur a epentier;
<:vspace>
afficher epentier > entier;
afficher epentier superieur a entier;
<:vspace>
<:vspace>
afficher epentier < entier;
afficher epentier inferieur a entier;
<:vspace>
afficher entier < epentier;
afficher entier inferieur a epentier;
<:vspace>
<:vspace>
afficher entier >= epentier;
afficher entier superieur ou egal a epentier;
<:vspace>
afficher epentier >= entier;
afficher epentier superieur ou egal a entier;
afficher epentier >= 30;
<:vspace>
<:vspace>
afficher epentier <= entier;
afficher epentier inferieur ou egal a entier;
<:vspace>
afficher entier <= epentier;
afficher entier inferieur ou egal a epentier;
afficher entier <= 6;
<:vspace>
<:vspace>
afficher entier dans [5;6[;
afficher entier dans [4;5];
afficher entier dans ]6;7];
<:vspace>
afficher entier compris dans [6;7[;
afficher entier compris dans [6;7];
afficher entier compris dans ]5;7];
(:sourcend:)
Normalement la compilation a du bien se passer et vous devez avoir un fichier programme.c de généré. On le lance :
⚠ (:source lang=bash:)
gcc -o programme programme.c
./programme
(:sourcend:)
Et on obtient ceci :
⚠ (:source lang=text:)
faux
faux
vrai
vrai
faux
faux
faux
vrai
vrai
vrai
faux
faux
vrai
vrai
faux
faux
faux
vrai
vrai
vrai
faux
faux
vrai
vrai
faux
faux
vrai
vrai
faux
faux
vrai
vrai
vrai
faux
faux
vrai
vrai
vrai
faux
faux
faux
vrai
vrai
vrai
(:sourcend:)
Nous avons fini cette première évolution du langage. La prochaine sera la mise en place de conditions if/else. A bientôt donc pour l'évolution 2 !
<< Arbre syntaxique abstrait et Génération de code | Évolution 1 : Opérateurs de comparaison | Évolution 2 : If/Else >>
Thomas - (CC BY-NC-SA 3.0 FR)
